5 POKE53280,12:POKE53281,12:POKE646,1:PRINT"[147]"
10 PRINT"MIT DEM NACHFOLGENDEN PROGRAMM, DAS DU"
11 PRINT"ALS UNTERPROGRAMM AN DEIN PROGGI AN-"
12 PRINT"HAENGEN KANNST, KANNST DU EINEN ZEICHEN-SATZ, DEN DU MIT DEM ZS-GENERATOR"
13 PRINT"ERSTELLT HAST, LADEN UND ANZEIGEN."
14 PRINT"DAZU LOESCHE ALLE ZEILEN BIS 19999      UND BEFOLGE DIE NACH DEM FILE"
15 PRINT"UNTER 'REM' ANGEGEBENEN ANWEISUNGEN!"
16 PRINT"MIT DEN ZEILEN AB  20200  KANNST DU     DURCH 'GOSUB'-AUFRUF"
17 PRINT"DEN ZEICHENSATZ WIEDER AUSSCHALTEN!     ('RETURN' NACH UMSCHALTUNG!)"
18 PRINT"ZUM ANZEIGEN DRUECK JETZT 'RETURN',     ZUM BEENDEN 'SPACE'!"
19 A$="":GETA$:IFA$<>CHR$(13)ANDA$<>" "THEN19
20 IFA$=" "THENEND
21 IFA$=CHR$(13)ANDAN=0THEN20000
22 IFA$=CHR$(13)ANDAN=1THENAN=2:GOSUB20200:GOTO10
23 IFA$=CHR$(13)ANDAN=2THENEND
20000 REM LADEN DES ZEICHENSATZES
20001 :
20005 POKE 56,127:POKE55,0:CLR:REM BASIC GRENZE
20010 NA$="SCHLITZ"
20011 :
20020 SYS 57812 "0:"+NA$+".ZSA,S,R",8:REM FILENAME UND GERAETE ADRESSE
20030 POKE 782,136: REM HI  STARTADRESSE
20040 POKE 781,  0: REM LO  STARTADRESSE
20050 POKE 780,0  : REM LOAD/V. FLAG
20060 SYS 65493   : REM LOAD-ROUTINE
20080 V=53248
20090 POKE 56576,PEEK(56576) AND 253
20100 POKE V+24,2*1+16*0
20105 REM 'POKE 648,4' DANN IST ALLES WIEDER NORMAL!
20110 POKE 648,128:PRINT"[147]"
20120 ZE=34816:REM 8800H  ZEICHENSATZ
20130 BI=32768:REM 8000H  BILDSCHIRM
20135 :
20140 AN=1:GOTO 10 : REM 'AN' BITTE                               LOESCHEN!
20150 :
20200 REM   NORMAL
20210 POKE648,4 :PRINT"[147]"
20220 POKE 53248+24,21
20230 POKE 56576,151
20240 RETURN
20250 REM  ----------------------------
20260 REM ------------------------------
20270 REM  IN ZEILE 20140 WIRD ANSTATT
20280 REM  '10'  DIE RUECKSPRUNG-ZEILE
20290 REM          EINGEGEBEN
20295 REM  ---------------------------
20296 REM ------------------------------
20300 REM  IN ZEILE 20010 WIRD DER
20310 REM  FILENAME DES ZEICHENSATZES
20320 REM  EINGETRAGEN, DER GELADEN
20330 REM  WERDEN SOLL    (ANSTELLE
20400 REM                 'SCHLTZ')
20410 REM  ---------------------------
20420 REM  -----------------------------
20430 REM  DIE 'REM'-ZEILEN IM PROGRAMM
20440 REM  KANNST DU NATUERLICH AUCH
20450 REM  KOMPLETT ENTFERNEN!
20455 REM
20460 REM  ---------------------------
20470 REM  ---------------------------